Instalar várias fontes via GPO

Explicaremos de uma maneira breve um meio de criar uma GPO para instalar várias fontes. Entendemos que quando são muitas fontes, ou quando é necessário adicionar novas fontes com o tempo, é uma maneira mais automática (do que toda vez alterar dois itens na política, um para copiar o arquivo e outra para criar chave no registro).

Vamos considerar aqui que você já tem alguma intimidade com administração de GPOs e redes, deixaremos em cinza algumas partes que você pode querer alterar conforme e deixar de outra forma.

Crie uma pasta chamada Fontes no compartilhamento Netlogon de seu AD. Copie os arquivos TTF de fonte que você deseja que sejam instalados.

Parar criar o script, abra o notepad e insira o conteúdo abaixo (IMPORTANTE: algumas aspas podem ficar alteradas durante a cópia, sugerimos alterar tanto as aspas simples quanto as aspas duplas após colar o código):

'********************************************************************************
' SCRIPT PARA INSTALAR TODAS AS FONTES QUE ESTÃO EM UMA PASTA NO SERVIDOR
' FONTE: nvlan.com.br
'********************************************************************************
Option Explicit
dim WinScriptHost
Dim objShell, objFSO, wshShell
Dim strFontSourcePath, objFolder, objFont, objNameSpace, objFile, CopiarFontesDe
Set objShell = CreateObject("Shell.Application")
Set wshShell = CreateObject("WScript.Shell")
Set objFSO = createobject("Scripting.Filesystemobject")
'********************************************************************************
' VARIAVEIS (ALTERE CONFORME A NECESSIDADE)
'********************************************************************************
CopiarFontesDe = "\\SEU_DOMINIO.COM.BR\Netlogon\Fontes"
'********************************************************************************
'                                                              INICIO DO SCRIPT
'********************************************************************************
strFontSourcePath = objFSO.GetAbsolutePathName(CopiarFontesDe)
Set objNameSpace = objShell.Namespace(strFontSourcePath)
Set objFolder = objFSO.getFolder(strFontSourcePath)
For Each objFile In objFolder.files
  If LCase(right(objFile,4)) = ".ttf" OR LCase(right(objFile,4)) = ".otf" Then
    Set objFont = objNameSpace.ParseName(objFile.Name)
    If objFSO.FileExists("C:\WINDOWS\Fonts\" & objFile.Name) = False Then
      objFont.InvokeVerb("Install")
      Set objFont = Nothing
    End If
  End If
Next

Na hora de salvar o arquivo, mude o tipo de extensão para todo o tipo de arquivo e salve localmente em seu computador como fonts.vbs. Agora abra o mmc, insira e abra o gerenciador de políticas de domínio, vá na OU que você deseja criar a política, nesta OU crie e associe uma política chamada Instala Fontes.

Edite esta nova política e navegue até Computer Configuration -> Policies -> Windows Configuration -> Scripts e abra Startup. Clique em Add, na tela seguinte coloque o nome fonts.vbs e clique em OK.

De volta a tela anterior clique em Show Files, na tela do explorer que abrir mova o arquivo fonts.vbs criado para esta pasta.

Mais Informações

Esperamos ter ajudado da melhor forma possível e estaremos sempre a disposição para mais informações.

Entre em contato conosco pelo e-mail equipe@nvlan.com.br.